| #!/usr/bin/perl -w |
| use strict; |
| use XML::LibXML; |
| |
| # This script is called thus : |
| # |
| # make_opengl [opengl_version] |
| # |
| # - It needs files from the OpenGL extension registry: |
| # |
| # https://raw.github.com/KhronosGroup/OpenGL-Registry/master/xml/gl.xml |
| # https://raw.github.com/KhronosGroup/OpenGL-Registry/master/xml/wgl.xml |
| # |
| # If they are not found in the current directory the script will |
| # attempt to download them from there. |
| # |
| # - opengl_version is the OpenGL version emulated by the library |
| # (can be 1.0 to 1.5). The default is 1.1. |
| # |
| # This script generates the three following files : |
| # |
| # - opengl32.spec : the spec file giving all the exported functions |
| # of the OpenGL32.DLL library. These functions are the one an |
| # application can directly link to (and are all the functions |
| # defined in the OpenGL core for the version defined by |
| # 'opengl_version'). |
| # |
| # - opengl_norm.c : this file contains the thunks for all OpenGL |
| # functions that are defined in 'opengl32.spec'. The corresponding |
| # functions NEED to be defined in Linux's libGL or the library |
| # won't be able to be linked in. |
| # |
| # - opengl_ext.c : in this file are stored thunks for ALL possible |
| # OpenGL extensions (at least, all the extensions that are defined |
| # in the OpenGL extension registry). Contrary to 'opengl_norm.c', |
| # you do not need to have these extensions in your libGL to have |
| # OpenGL work (as they are resolved at run-time using |
| # glXGetProcAddressARB). |
| # |
| # - include/wine/wgl_driver.h: definitions for the tables of OpenGL functions. |
| # |
| # |
| # Copyright 2000 Lionel Ulmer |
| # Copyright 2012 Alexandre Julliard |
| # |
| # This library is free software; you can redistribute it and/or |
| # modify it under the terms of the GNU Lesser General Public |
| # License as published by the Free Software Foundation; either |
| # version 2.1 of the License, or (at your option) any later version. |
| # |
| # This library is distributed in the hope that it will be useful, |
| # but WITHOUT ANY WARRANTY; without even the implied warranty of |
| # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| # Lesser General Public License for more details. |
| # |
| # You should have received a copy of the GNU Lesser General Public |
| # License along with this library; if not, write to the Free Software |
| # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA |
| # |
| |
| # |
| # Files to generate |
| # |
| my $spec_file = "opengl32.spec"; |
| my $norm_file = "opengl_norm.c"; |
| my $ext_file = "opengl_ext.c"; |
| my $wgl_driver_file = "../../include/wine/wgl_driver.h"; |
| my $wgl_file = "../../include/wine/wgl.h"; |
| |
| # If set to 1, generate TRACEs for each OpenGL function |
| my $gen_traces = 1; |
| |
| # |
| # List of categories to put in the 'opengl_norm.c' file |
| # |
| my %cat_1_0 = ( "GL_VERSION_1_0" => 1 ); |
| my %cat_1_1 = ( %cat_1_0, "GL_VERSION_1_1" => 1 ); |
| my %cat_1_2 = ( %cat_1_1, "GL_VERSION_1_2" => 1 ); |
| my %cat_1_3 = ( %cat_1_2, "GL_VERSION_1_3" => 1 ); |
| my %cat_1_4 = ( %cat_1_3, "GL_VERSION_1_4" => 1 ); |
| my %cat_1_5 = ( %cat_1_4, "GL_VERSION_1_5" => 1 ); |
| |
| my %norm_categories = (); |
| |
| # |
| # This hash table gives the conversion between OpenGL types and |
| # the .spec type and debug format |
| # |
| my %arg_types = |
| ( |
| "GLbitfield" => [ "long", "%d" ], |
| "GLboolean" => [ "long", "%d" ], |
| "GLbyte" => [ "long", "%d" ], |
| "GLchar" => [ "long", "%c" ], |
| "GLcharARB" => [ "long", "%c" ], |
| "GLclampd" => [ "double", "%f" ], |
| "GLclampf" => [ "float", "%f" ], |
| "GLclampx" => [ "long", "%d" ], |
| "GLdouble" => [ "double", "%f" ], |
| "GLeglClientBufferEXT" => [ "ptr", "%p" ], |
| "GLenum" => [ "long", "%d" ], |
| "GLfixed" => [ "long", "%d" ], |
| "GLfloat" => [ "float", "%f" ], |
| "GLhalfNV" => [ "long", "%d" ], |
| "GLhandleARB" => [ "long", "%d" ], |
| "GLint" => [ "long", "%d" ], |
| "GLint64" => [ "int64", "wine_dbgstr_longlong(%s)" ], |
| "GLint64EXT" => [ "int64", "wine_dbgstr_longlong(%s)" ], |
| "GLintptr" => [ "long", "%ld" ], |
| "GLintptrARB" => [ "long", "%ld" ], |
| "GLshort" => [ "long", "%d" ], |
| "GLsizei" => [ "long", "%d" ], |
| "GLsizeiptr" => [ "long", "%ld" ], |
| "GLsizeiptrARB" => [ "long", "%ld" ], |
| "GLstring" => [ "str", "wine_dbgstr_a(%s)" ], |
| "GLsync" => [ "ptr", "%p" ], |
| "GLubyte" => [ "long", "%d" ], |
| "GLuint" => [ "long", "%d" ], |
| "GLuint64" => [ "int64", "wine_dbgstr_longlong(%s)" ], |
| "GLuint64EXT" => [ "int64", "wine_dbgstr_longlong(%s)" ], |
| "GLushort" => [ "long", "%d" ], |
| "GLvdpauSurfaceNV" => [ "long", "%ld" ], |
| "GLDEBUGPROC" => [ "ptr", "%p" ], |
| "GLDEBUGPROCARB" => [ "ptr", "%p" ], |
| "GLDEBUGPROCAMD" => [ "ptr", "%p" ], |
| "GLDEBUGPROCKHR" => [ "ptr", "%p" ], |
| "GLVULKANPROCNV" => [ "ptr", "%p" ], |
| "HDC" => [ "long", "%p" ], |
| "HGLRC" => [ "long", "%p" ], |
| "HPBUFFERARB" => [ "long", "%p" ], |
| "HENHMETAFILE" => [ "long", "%p" ], |
| "LPGLYPHMETRICSFLOAT" => [ "ptr", "%p" ], |
| "LPCSTR" => [ "str", "wine_dbgstr_a(%s)" ], |
| "UINT" => [ "long", "%u" ], |
| "DWORD" => [ "long", "%u" ], |
| "BOOL" => [ "long", "%u" ], |
| "FLOAT" => [ "float", "%f" ], |
| ); |
| |
| my %remap_types = |
| ( |
| "HGLRC" => "struct wgl_context *", |
| "HPBUFFERARB" => "struct wgl_pbuffer *", |
| ); |
| # |
| # Used to convert some types |
| # |
| sub ConvertType($) |
| { |
| my $arg = shift; |
| my $ret = $arg->textContent(); |
| my @type = $arg->findnodes("./ptype"); |
| |
| if (@type) |
| { |
| my $type = $type[0]->textContent(); |
| $ret =~ s/$type/$remap_types{$type}/ if defined $remap_types{$type}; |
| } |
| return $ret; |
| } |
| |
| # |
| # This functions generates the thunk for a given function. |
| # |
| sub GenerateThunk($$$) |
| { |
| my ($name, $func_ref, $prefix) = @_; |
| my $call_arg = ""; |
| my $trace_call_arg = ""; |
| my $trace_arg = ""; |
| |
| return "" if $name eq "glDebugEntry"; |
| return "" if $name eq "glGetIntegerv"; |
| return "" if $name eq "glGetString"; |
| return "" if $func_ref->[2] && $func_ref->[2]->[0] =~ /WGL_/; |
| |
| my $ret = get_func_proto( "%s WINAPI %s(%s)", $name, $func_ref ); |
| foreach my $arg (@{$func_ref->[1]}) { |
| my $ptype = get_arg_type( $arg ); |
| my $pname = get_arg_name( $arg ); |
| my $param = $arg->textContent(); |
| $call_arg .= " " . $pname . ","; |
| if ($param =~ /\*/ || $param =~ /\[/) { |
| $trace_arg .= ", %p"; |
| $trace_call_arg .= ", " . $pname; |
| } elsif (defined $arg_types{$ptype}) { |
| my $format = ${$arg_types{$ptype}}[1]; |
| $trace_arg .= ", " . ($format =~ /^%/ ? $format : "%s"); |
| $trace_call_arg .= ", " . sprintf $format =~ /^%/ ? "%s" : $format, $pname; |
| } |
| else { printf "Unknown type %s in %s\n", $param, $name; } |
| } |
| $call_arg =~ s/,$/ /; |
| $trace_arg =~ s/^, //; |
| return "$ret DECLSPEC_HIDDEN;\n" if $name eq "glGetStringi"; |
| $ret .= "\n{\n const struct opengl_funcs *funcs = NtCurrentTeb()->glTable;\n"; |
| $ret .= " TRACE( \"($trace_arg)\\n\"$trace_call_arg );\n" if $gen_traces; |
| $ret .= " "; |
| $ret .= "return " unless is_void_func( $func_ref ); |
| $ret .= "funcs->$prefix.p_$name($call_arg);\n"; |
| $ret .= "}\n"; |
| return $ret; |
| } |
| |
| sub generate_null_func($$) |
| { |
| my ($name, $func_ref) = @_; |
| my $ret; |
| |
| return "" if $name eq "glDebugEntry"; |
| |
| $ret = get_func_proto( "static %s null_%s(%s)", $name, $func_ref ); |
| $ret .= " {"; |
| if ($name eq "glGetError") |
| { |
| $ret .= " return GL_INVALID_OPERATION;"; |
| } |
| elsif (!is_void_func( $func_ref )) |
| { |
| $ret .= " return 0;"; |
| } |
| $ret .= " }\n"; |
| return $ret; |
| } |
| |
| sub generate_spec_entry($$) |
| { |
| my ($name, $func) = @_; |
| my $args=" "; |
| foreach my $arg (@{$func->[1]}) |
| { |
| my $ptype = get_arg_type( $arg ); |
| my $param = $arg->textContent(); |
| if ($param =~ /[[*]/) { |
| $args .= "ptr "; |
| } elsif (defined($arg_types{$ptype})) { |
| $args .= "$@$arg_types{$ptype}[0] "; |
| } else { |
| die "No conversion for func $name type $param\n"; |
| } |
| } |
| $args = substr($args,1,-1); |
| return "@ stdcall $_($args)"; |
| } |
| |
| sub is_void_func($) |
| { |
| my $func = shift; |
| return 0 if @{$func->[0]->findnodes("./ptype")}; |
| return $func->[0]->textContent() eq "void "; |
| } |
| |
| sub get_arg_type($) |
| { |
| my $p = shift; |
| my @type = $p->findnodes("./ptype"); |
| return @type ? $type[0]->textContent() : "GLint"; |
| } |
| |
| sub get_arg_name($) |
| { |
| my $p = shift; |
| my @name = $p->findnodes("./name"); |
| return $name[0]->textContent(); |
| } |
| |
| sub get_func_proto($$$) |
| { |
| my ($format, $name, $func) = @_; |
| die "unknown func $name" unless defined $func->[0]; |
| my $proto = ConvertType( $func->[0] ); |
| $proto =~ s/ $//; |
| my $args = ""; |
| foreach my $arg (@{$func->[1]}) |
| { |
| $args .= " " . ConvertType( $arg ) . ","; |
| } |
| $args =~ s/,$/ /; |
| $args ||= "void"; |
| return sprintf $format, $proto, $name, $args; |
| } |
| |
| # |
| # Extract and checks the number of arguments |
| # |
| if (@ARGV > 1) { |
| my $name0=$0; |
| $name0=~s%^.*/%%; |
| die "Usage: $name0 [version]\n"; |
| } |
| my $version = $ARGV[0] || "1.1"; |
| if ($version eq "1.0") { |
| %norm_categories = %cat_1_0; |
| } elsif ($version eq "1.1") { |
| %norm_categories = %cat_1_1; |
| } elsif ($version eq "1.2") { |
| %norm_categories = %cat_1_2; |
| } elsif ($version eq "1.3") { |
| %norm_categories = %cat_1_3; |
| } elsif ($version eq "1.4") { |
| %norm_categories = %cat_1_4; |
| } elsif ($version eq "1.5") { |
| %norm_categories = %cat_1_5; |
| } else { |
| die "Incorrect OpenGL version.\n"; |
| } |
| |
| # |
| # Fetch the registry files |
| # |
| -f "gl.xml" || system "wget https://raw.github.com/KhronosGroup/OpenGL-Registry/master/xml/gl.xml" || die "cannot download gl.xml"; |
| -f "wgl.xml" || system "wget https://raw.github.com/KhronosGroup/OpenGL-Registry/master/xml/wgl.xml" || die "cannot download wgl.xml"; |
| |
| |
| # |
| # Then, create the list of all OpenGL functions using the registry |
| # files. This will create two hash-tables, one with all the function |
| # whose category matches the one listed in '@norm_categories', the other |
| # with all other functions. |
| # |
| # An element of the hash table is a reference to an array with these |
| # elements : |
| # |
| # - XML node of the function prototype |
| # |
| # - reference to an array of XML nodes giving the list of arguments (an empty array |
| # for a 'void' function). |
| # |
| my %norm_functions; |
| my %ext_functions; |
| my %wgl_functions; |
| my (%gl_types, @gl_types); # also use an array to preserve declaration order |
| |
| my %supported_wgl_functions = |
| ( |
| "wglCopyContext" => 1, |
| "wglCreateContext" => 1, |
| "wglDeleteContext" => 1, |
| "wglDescribePixelFormat" => 1, |
| "wglGetPixelFormat" => 1, |
| "wglGetProcAddress" => 1, |
| "wglMakeCurrent" => 1, |
| "wglSetPixelFormat" => 1, |
| "wglShareLists" => 1, |
| "wglSwapBuffers" => 1, |
| ); |
| |
| my %remapped_wgl_functions = |
| ( |
| "ChoosePixelFormat" => "wglChoosePixelFormat", |
| "DescribePixelFormat" => "wglDescribePixelFormat", |
| "GetPixelFormat" => "wglGetPixelFormat", |
| "GetEnhMetaFilePixelFormat" => 0, |
| "SetPixelFormat" => "wglSetPixelFormat", |
| "SwapBuffers" => "wglSwapBuffers", |
| "wglUseFontBitmaps" => 0, |
| "wglUseFontOutlines" => 0, |
| ); |
| |
| my %supported_wgl_extensions = |
| ( |
| "WGL_ARB_create_context" => 1, |
| "WGL_ARB_extensions_string" => 1, |
| "WGL_ARB_make_current_read" => 1, |
| "WGL_ARB_pbuffer" => 1, |
| "WGL_ARB_pixel_format" => 1, |
| "WGL_ARB_render_texture" => 1, |
| "WGL_EXT_extensions_string" => 1, |
| "WGL_EXT_swap_control" => 1, |
| "WGL_NV_vertex_array_range" => 1, |
| "WGL_WINE_pixel_format_passthrough" => 1, |
| "WGL_WINE_query_renderer" => 1, |
| ); |
| |
| my %enums; |
| |
| my %supported_apis = |
| ( |
| "gl" => 1, |
| ); |
| |
| sub is_supported_api($) |
| { |
| my $api = shift; |
| foreach my $i (split /\|/, $api) |
| { |
| return 1 if defined $supported_apis{$i}; |
| } |
| return 0; |
| } |
| |
| sub parse_file($$) |
| { |
| my ($file, $generate_enums) = @_; |
| my $xml = XML::LibXML->load_xml( location => $file ); |
| my %functions; |
| |
| # save all functions |
| foreach my $command ($xml->findnodes("/registry/commands/command")) |
| { |
| my $proto = @{$command->findnodes("./proto")}[0]; |
| my $name = @{$command->findnodes("./proto/name")}[0]; |
| $proto->removeChild( $name ); |
| my @params = $command->findnodes("./param"); |
| $functions{$name->textContent()} = [ $proto, \@params ]; |
| } |
| |
| # save all enums (only GL) |
| if ($generate_enums) |
| { |
| foreach my $enum ($xml->findnodes("/registry/enums/enum")) |
| { |
| $enums{$enum->{name}} = $enum->{value}; |
| } |
| } |
| |
| # save all types |
| foreach my $type ($xml->findnodes("/registry/types/type")) |
| { |
| next if $type->{api}; |
| my $name = @{$type->findnodes("./name")}[0]; |
| next unless $name; |
| $name = $name->textContent; |
| push @gl_types, $name unless $gl_types{$name}; |
| $gl_types{$name} = $type; |
| } |
| |
| # generate norm functions |
| foreach my $feature ($xml->findnodes("/registry/feature")) |
| { |
| if ($feature->{api} eq "wgl") |
| { |
| foreach my $cmd ($feature->findnodes("./require/command")) |
| { |
| my $name = $cmd->{name}; |
| if (defined $remapped_wgl_functions{$name}) |
| { |
| next unless $remapped_wgl_functions{$name}; |
| $name = $remapped_wgl_functions{$name}; |
| } |
| $wgl_functions{$name} = $functions{$cmd->{name}}; |
| } |
| } |
| next unless defined $norm_categories{$feature->{name}}; |
| foreach my $cmd ($feature->findnodes("./require/command")) |
| { |
| $norm_functions{$cmd->{name}} = $functions{$cmd->{name}}; |
| } |
| } |
| |
| # generate extension functions from norm functions, if they are newer than the category |
| foreach my $feature ($xml->findnodes("/registry/feature")) |
| { |
| next if defined $norm_categories{$feature->{name}}; |
| next unless is_supported_api( $feature->{api} ); |
| foreach my $cmd ($feature->findnodes("./require/command")) |
| { |
| my $name = $cmd->{name}; |
| next if $norm_functions{$name} || $ext_functions{$name}; |
| $ext_functions{$name} = [ $functions{$name}[0], $functions{$name}[1], [ $feature->{name} ] ]; |
| } |
| } |
| |
| # generate extension functions |
| foreach my $ext ($xml->findnodes("/registry/extensions/extension")) |
| { |
| if ($ext->{supported} eq "wgl") |
| { |
| next unless defined $supported_wgl_extensions{$ext->{name}}; |
| foreach my $cmd ($ext->findnodes("./require/command")) |
| { |
| my $name = $cmd->{name}; |
| $ext_functions{$name} = [ $functions{$name}[0], $functions{$name}[1], [ $ext->{name} ] ]; |
| } |
| next; |
| } |
| next unless is_supported_api( $ext->{supported} ); |
| foreach my $req ($ext->findnodes("./require")) |
| { |
| next unless !$req->{api} || $req->{api} eq "gl"; |
| foreach my $cmd ($req->findnodes("./command")) |
| { |
| my $name = $cmd->{name}; |
| next if $norm_functions{$name}; |
| if (!$ext_functions{$name}) |
| { |
| $ext_functions{$name} = [ $functions{$name}[0], $functions{$name}[1], [ $ext->{name} ] ]; |
| } |
| else |
| { |
| push @{$ext_functions{$name}->[2]}, $ext->{name}; |
| } |
| } |
| } |
| } |
| } |
| |
| parse_file( "gl.xml", 1 ); |
| parse_file( "wgl.xml", 0 ); |
| parse_file( "winegl.xml", 1 ); |
| |
| # |
| # Get the current wgl_driver.h version |
| # |
| my $wgl_version = 0; |
| open HEADER, "<$wgl_driver_file" or die "cannot open $wgl_driver_file"; |
| while (<HEADER>) |
| { |
| next unless /^#define WINE_WGL_DRIVER_VERSION (\d+)/; |
| $wgl_version = $1; |
| last; |
| } |
| close HEADER; |
| |
| # |
| # Generate the wgl_driver.h file |
| # |
| open HEADER, ">$wgl_driver_file" or die "cannot create $wgl_driver_file"; |
| print HEADER "/* Automatically generated from http://www.opengl.org/registry files; DO NOT EDIT! */\n\n"; |
| print HEADER "#ifndef __WINE_WGL_DRIVER_H\n"; |
| print HEADER "#define __WINE_WGL_DRIVER_H\n\n"; |
| print HEADER "#ifndef WINE_GLAPI\n"; |
| print HEADER "#define WINE_GLAPI\n"; |
| print HEADER "#endif\n\n"; |
| |
| printf HEADER "#define WINE_WGL_DRIVER_VERSION %u\n\n", $wgl_version + 1; |
| |
| print HEADER "struct wgl_context;\n"; |
| print HEADER "struct wgl_pbuffer;\n\n"; |
| |
| print HEADER "struct opengl_funcs\n{\n"; |
| print HEADER " struct\n {\n"; |
| foreach (sort keys %wgl_functions) |
| { |
| next unless defined $supported_wgl_functions{$_}; |
| print HEADER get_func_proto(" %-10s (WINE_GLAPI *p_%s)(%s);\n", $_, $wgl_functions{$_}); |
| } |
| print HEADER " } wgl;\n\n"; |
| |
| print HEADER " struct\n {\n"; |
| foreach (sort keys %norm_functions) |
| { |
| next if $_ eq "glDebugEntry"; |
| print HEADER get_func_proto(" %-10s (WINE_GLAPI *p_%s)(%s);\n", $_, $norm_functions{$_}); |
| } |
| print HEADER " } gl;\n\n"; |
| |
| print HEADER " struct\n {\n"; |
| foreach (sort keys %ext_functions) |
| { |
| print HEADER get_func_proto(" %-10s (WINE_GLAPI *p_%s)(%s);\n", $_, $ext_functions{$_}); |
| } |
| print HEADER " } ext;\n"; |
| print HEADER "};\n\n"; |
| |
| print HEADER "#define ALL_WGL_FUNCS"; |
| foreach (sort keys %norm_functions) |
| { |
| next if $_ eq "glDebugEntry"; |
| printf HEADER " \\\n USE_GL_FUNC(\%s)", $_; |
| } |
| print HEADER "\n\n"; |
| |
| print HEADER "extern struct opengl_funcs * CDECL __wine_get_wgl_driver( HDC hdc, UINT version );\n"; |
| print HEADER "extern BOOL CDECL __wine_set_pixel_format( HWND hwnd, int format );\n\n"; |
| print HEADER "#endif /* __WINE_WGL_DRIVER_H */\n"; |
| close HEADER; |
| |
| # |
| # Generate the wgl.h file |
| # |
| open HEADER, ">$wgl_file" or die "cannot create $wgl_file"; |
| print HEADER "/* Automatically generated from http://www.opengl.org/registry files; DO NOT EDIT! */\n\n"; |
| print HEADER "#ifndef __WINE_WGL_H\n"; |
| print HEADER "#define __WINE_WGL_H\n\n"; |
| |
| print HEADER "#ifndef GLAPIENTRY\n"; |
| print HEADER "#define GLAPIENTRY __stdcall\n"; |
| print HEADER "#endif\n\n"; |
| |
| print HEADER "#undef near\n"; |
| print HEADER "#undef far\n\n"; |
| |
| foreach (@gl_types) |
| { |
| printf HEADER $gl_types{$_}->textContent() . "\n"; |
| } |
| print HEADER "\n"; |
| |
| my $maxlen = 1; |
| foreach (keys %enums) { $maxlen = length($_) if length($_) > $maxlen; } |
| foreach (sort keys %enums) |
| { |
| printf HEADER "#define %-*s %s\n", $maxlen, $_, $enums{$_}; |
| } |
| print HEADER "\n"; |
| |
| foreach (sort keys %norm_functions) |
| { |
| printf HEADER "%s;\n", get_func_proto("%-10s GLAPIENTRY %s(%s)", $_, $norm_functions{$_}); |
| } |
| |
| print HEADER "\n#endif /* __WINE_WGL_H */\n"; |
| close HEADER; |
| |
| # |
| # Now, generate the output files. First, the spec file. |
| # |
| open(SPEC, ">$spec_file") or die "cannot create $spec_file"; |
| |
| foreach (sort keys %norm_functions) { |
| printf SPEC "%s\n", generate_spec_entry( $_, $norm_functions{$_} ); |
| } |
| foreach (sort keys %wgl_functions) { |
| printf SPEC "%s\n", generate_spec_entry( $_, $wgl_functions{$_} ); |
| } |
| |
| close(SPEC); |
| |
| # |
| # After the spec file, the opengl_norm.c file |
| # |
| open(NORM, ">$norm_file") or die "cannot create $norm_file"; |
| print NORM " |
| /* Auto-generated file... Do not edit ! */ |
| |
| #include \"config.h\" |
| #include <stdarg.h> |
| #include \"winternl.h\" |
| #include \"wingdi.h\" |
| #include \"wine/wgl.h\" |
| #include \"wine/wgl_driver.h\" |
| #include \"wine/debug.h\" |
| |
| WINE_DEFAULT_DEBUG_CHANNEL(opengl); |
| "; |
| |
| foreach (sort keys %norm_functions) { |
| my $string = GenerateThunk($_, $norm_functions{$_}, "gl"); |
| print NORM "\n$string" if $string; |
| } |
| |
| foreach (sort keys %wgl_functions) { |
| next unless defined $supported_wgl_functions{$_}; |
| print NORM generate_null_func($_, $wgl_functions{$_}); |
| } |
| foreach (sort keys %norm_functions) { |
| print NORM generate_null_func($_, $norm_functions{$_}); |
| } |
| foreach (sort keys %ext_functions) { |
| print NORM generate_null_func($_, $ext_functions{$_}); |
| } |
| |
| print NORM "\nstruct opengl_funcs null_opengl_funcs =\n{\n {\n"; |
| foreach (sort keys %wgl_functions) |
| { |
| next unless defined $supported_wgl_functions{$_}; |
| print NORM " null_$_,\n"; |
| } |
| print NORM " },\n {\n"; |
| foreach (sort keys %norm_functions) { print NORM " null_$_,\n" unless $_ eq "glDebugEntry"; } |
| print NORM " },\n {\n"; |
| foreach (sort keys %ext_functions) { print NORM " null_$_,\n"; } |
| print NORM " }\n};\n"; |
| |
| close(NORM); |
| |
| # |
| # Finally, more complex, the opengl_ext.c file |
| # |
| open(EXT, ">$ext_file") or die "cannot create $ext_file"; |
| print EXT " |
| /* Auto-generated file... Do not edit ! */ |
| |
| #include \"config.h\" |
| #include <stdarg.h> |
| #include \"opengl_ext.h\" |
| #include \"winternl.h\" |
| #include \"wingdi.h\" |
| #include \"wine/wgl.h\" |
| #define WGL_WGLEXT_PROTOTYPES |
| #include \"wine/wglext.h\" |
| #include \"wine/wgl_driver.h\" |
| #include \"wine/debug.h\" |
| |
| WINE_DEFAULT_DEBUG_CHANNEL(opengl); |
| |
| "; |
| |
| # The thunks themselves.... |
| my $count = keys %ext_functions; |
| print EXT "const int extension_registry_size = $count;\n"; |
| foreach (sort keys %ext_functions) { |
| my $string = GenerateThunk($_, $ext_functions{$_}, "ext"); |
| if ($string =~ /DECLSPEC_HIDDEN/) { |
| print EXT "\n$string"; |
| } else { |
| print EXT "\nstatic $string" if $string; |
| } |
| } |
| |
| # Then the table giving the string <-> function correspondence */ |
| print EXT "\nconst OpenGL_extension extension_registry[$count] = {\n"; |
| my $i = 0; |
| foreach (sort keys %ext_functions) { |
| my $func_ref = $ext_functions{$_}; |
| printf EXT " { \"%s\", \"%s\", %s }", $_, join(" ", sort @{$func_ref->[2]}), $_; |
| if ($i != $count-1) { |
| print EXT ","; |
| } |
| $i++; |
| print EXT "\n"; |
| } |
| print EXT "};\n"; |
| |
| close(EXT); |
