| dnl Macros used to build the Wine configure script | |
| dnl | |
| dnl Copyright 2002 Alexandre Julliard | |
| dnl | |
| dnl This library is free software; you can redistribute it and/or | |
| dnl modify it under the terms of the GNU Lesser General Public | |
| dnl License as published by the Free Software Foundation; either | |
| dnl version 2.1 of the License, or (at your option) any later version. | |
| dnl | |
| dnl This library is distributed in the hope that it will be useful, | |
| dnl but WITHOUT ANY WARRANTY; without even the implied warranty of | |
| dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU | |
| dnl Lesser General Public License for more details. | |
| dnl | |
| dnl You should have received a copy of the GNU Lesser General Public | |
| dnl License along with this library; if not, write to the Free Software | |
| dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA | |
| dnl | |
| dnl As a special exception to the GNU Lesser General Public License, | |
| dnl if you distribute this file as part of a program that contains a | |
| dnl configuration script generated by Autoconf, you may include it | |
| dnl under the same distribution terms that you use for the rest of | |
| dnl that program. | |
| dnl **** Get the ldd program name; used by WINE_GET_SONAME **** | |
| dnl | |
| dnl Usage: WINE_PATH_LDD | |
| dnl | |
| AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)]) | |
| dnl **** Extract the soname of a library **** | |
| dnl | |
| dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES]) | |
| dnl | |
| AC_DEFUN([WINE_GET_SONAME], | |
| [AC_REQUIRE([WINE_PATH_LDD]) | |
| AC_CACHE_CHECK([for -l$1 soname], ac_cv_lib_soname_$1, | |
| [ac_get_soname_save_LIBS=$LIBS | |
| LIBS="-l$1 $3 $LIBS" | |
| AC_LINK_IFELSE([AC_LANG_CALL([], [$2])], | |
| [ac_cv_lib_soname_$1=`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.$LIBEXT | sed "s/^.*\(lib$1\.$LIBEXT[[^ ]]*\).*$/\1/"` | |
| if test "x$ac_cv_lib_soname_$1" = "x" | |
| then | |
| ac_cv_lib_soname_$1="lib$1.$LIBEXT" | |
| fi], | |
| [ac_cv_lib_soname_$1="lib$1.$LIBEXT"]) | |
| LIBS=$ac_get_soname_save_LIBS]) | |
| if test "x$ac_cv_lib_soname_$1" != xNONE | |
| then AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),"$ac_cv_lib_soname_$1", | |
| [Define to the soname of the lib$1 library.])dnl | |
| fi]) | |
| dnl **** Link C code with an assembly file **** | |
| dnl | |
| dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]]) | |
| dnl | |
| AC_DEFUN([WINE_TRY_ASM_LINK], | |
| [AC_TRY_LINK([void ac_asm(void) { asm([$1]); } | |
| [$2]],[$3],[$4],[$5])]) | |
| dnl **** Check if we can link an empty program with special CFLAGS **** | |
| dnl | |
| dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]]) | |
| dnl | |
| AC_DEFUN([WINE_TRY_CFLAGS], | |
| [ac_wine_try_cflags_saved=$CFLAGS | |
| CFLAGS="$CFLAGS $1" | |
| AC_TRY_LINK([],[],[$2],[$3]) | |
| CFLAGS=$ac_wine_try_cflags_saved]) | |
| dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS **** | |
| dnl | |
| dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]]) | |
| dnl | |
| AC_DEFUN([WINE_TRY_SHLIB_FLAGS], | |
| [ac_wine_try_cflags_saved=$CFLAGS | |
| CFLAGS="$CFLAGS $1" | |
| AC_LINK_IFELSE([void myfunc() {}],[$2],[$3]) | |
| CFLAGS=$ac_wine_try_cflags_saved]) | |
| dnl **** Check whether we need to define a symbol on the compiler command line **** | |
| dnl | |
| dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]]) | |
| dnl | |
| AC_DEFUN([WINE_CHECK_DEFINE], | |
| [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl | |
| AC_CACHE_CHECK([whether we need to define $1],ac_var, | |
| AC_EGREP_CPP(yes,[#ifndef $1 | |
| yes | |
| #endif], | |
| [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)])) | |
| AS_IF([test AS_VAR_GET(ac_var) = yes], | |
| [CFLAGS="$CFLAGS -D$1" | |
| LINTFLAGS="$LINTFLAGS -D$1"])dnl | |
| AS_VAR_POPDEF([ac_var])]) | |
| dnl **** Check for ln **** | |
| dnl | |
| dnl Usage: WINE_PROG_LN | |
| dnl | |
| AC_DEFUN([WINE_PROG_LN], | |
| [AC_MSG_CHECKING([whether ln works]) | |
| rm -f conf$$ conf$$.file | |
| echo >conf$$.file | |
| if ln conf$$.file conf$$ 2>/dev/null; then | |
| AC_SUBST(LN,ln) | |
| AC_MSG_RESULT([yes]) | |
| else | |
| AC_SUBST(LN,["cp -p"]) | |
| AC_MSG_RESULT([no, using $LN]) | |
| fi | |
| rm -f conf$$ conf$$.file]) | |
| dnl **** Create nonexistent directories from config.status **** | |
| dnl | |
| dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname) | |
| dnl | |
| AC_DEFUN([WINE_CONFIG_EXTRA_DIR], | |
| [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])]) |