| dnl Process this file with autoconf to produce a configure script. |
| dnl Author: Michael Patra <micky@marie.physik.tu-berlin.de> |
| dnl <patra@itp1.physik.tu-berlin.de> |
| AC_REVISION([configure.in 1.00]) |
| AC_INIT(controls/edit.c) |
| AC_CONFIG_HEADER(include/config.h) |
| AC_CONFIG_AUX_DIR(tools) |
| |
| # We want these before the checks, so the checks can modify their values. |
| LIBS="$LIBS -lm" |
| test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT) |
| |
| dnl **** Command-line arguments **** |
| |
| dnl Default values |
| MAIN_TARGET=emu |
| LIB_TARGET=libwine.a |
| |
| AC_ARG_ENABLE(emulator, |
| [ --disable-emulator build only the Wine library, not the emulator], |
| [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi]) |
| |
| AC_ARG_ENABLE(dll, |
| [ --enable-dll build the Wine library as a DLL], |
| [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi]) |
| |
| dnl AC_ARG_WITH(ipc, |
| dnl [ --enable-ipc use inter-process communication for DDE], |
| dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi]) |
| |
| AC_ARG_WITH(reentrant-x, |
| [ --without-reentrant-x Compile for use with non-reentrant X libraries]) |
| |
| AC_SUBST(MAIN_TARGET) |
| AC_SUBST(LIB_TARGET) |
| AC_SUBST(OPTIONS) |
| |
| dnl **** Check for some programs **** |
| |
| AC_PROG_MAKE_SET |
| AC_PROG_CC |
| AC_PROG_CPP |
| AC_PATH_XTRA |
| AC_PROG_YACC |
| AC_PROG_LEX |
| AC_PROG_RANLIB |
| AC_PROG_INSTALL |
| AC_PROG_LN_S |
| |
| dnl **** Check for some libraries **** |
| |
| dnl Check for -li386 for NetBSD and OpenBSD |
| AC_CHECK_LIB(i386,i386_set_ldt) |
| dnl Check for -lw for Solaris |
| AC_CHECK_LIB(w,iswalnum) |
| dnl Check for XFree86 DGA extension |
| AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11) |
| |
| dnl **** Check for Open Sound System **** |
| |
| AC_CACHE_CHECK("for Open Sound System", |
| ac_cv_c_opensoundsystem, |
| AC_TRY_COMPILE([#include <sys/soundcard.h>],[ |
| /* check for one of the Open Sound System specific SNDCTL_ defines */ |
| #if !defined(SNDCTL_DSP_STEREO) |
| #error No open sound system |
| #endif |
| ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no")) |
| |
| AC_CACHE_CHECK("for Open Sound System on *BSD", |
| ac_cv_c_opensoundsystem_bsd, |
| AC_TRY_COMPILE([#include <machine/soundcard.h>],[ |
| /* check for one of the Open Sound System specific SNDCTL_ defines */ |
| #if !defined(SNDCTL_DSP_STEREO) |
| #error No open sound system |
| #endif |
| ],ac_cv_c_opensoundsystem_bsd="yes",ac_cv_c_opensoundsystem_bsd="no")) |
| |
| if test "$ac_cv_c_opensoundsystem" = "yes" -o "$ac_cv_c_opensoundsystem_bsd" = "yes" |
| then |
| AC_DEFINE(HAVE_OSS) |
| if test "$ac_cv_c_opensoundsystem_bsd" = "yes" |
| then |
| AC_DEFINE(HAVE_MACHINE_SOUNDCARD_H) |
| fi |
| fi |
| |
| dnl **** Check for union semun **** |
| |
| AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun, |
| AC_TRY_COMPILE([#include <sys/types.h> |
| #include <sys/sem.h>],[union semun foo], |
| ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no")) |
| if test "$ac_cv_c_union_semun" = "yes" |
| then |
| AC_DEFINE(HAVE_UNION_SEMUN) |
| fi |
| |
| dnl **** If ln -s doesn't work, use cp instead **** |
| if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi |
| |
| dnl **** Check for gcc strength-reduce bug **** |
| |
| if test "x${GCC}" = "xyes" |
| then |
| CFLAGS="$CFLAGS -Wall" |
| AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug, |
| AC_TRY_RUN([ |
| int main(void) { |
| static int Array[[3]]; |
| unsigned int B = 3; |
| int i; |
| for(i=0; i<B; i++) Array[[i]] = i - 3; |
| exit( Array[[1]] != -2 ); |
| }], |
| ac_cv_c_gcc_strength_bug="no", |
| ac_cv_c_gcc_strength_bug="yes", |
| ac_cv_c_gcc_strength_bug="yes") ) |
| if test "$ac_cv_c_gcc_strength_bug" = "yes" |
| then |
| CFLAGS="$CFLAGS -fno-strength-reduce" |
| fi |
| fi |
| |
| dnl **** Check for underscore on external symbols **** |
| |
| AC_CACHE_CHECK("whether external symbols need an underscore prefix", |
| ac_cv_c_extern_prefix, |
| [saved_libs=$LIBS |
| LIBS="conftest_asm.s $LIBS" |
| cat > conftest_asm.s <<EOF |
| .globl _ac_test |
| _ac_test: |
| .long 0 |
| EOF |
| AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1], |
| ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no") |
| LIBS=$saved_libs]) |
| if test "$ac_cv_c_extern_prefix" = "yes" |
| then |
| AC_DEFINE(NEED_UNDERSCORE_PREFIX) |
| fi |
| |
| dnl **** Check for .string in assembler **** |
| |
| AC_CACHE_CHECK("whether assembler accepts .string", |
| ac_cv_c_asm_string, |
| [saved_libs=$LIBS |
| LIBS="conftest_asm.s $LIBS" |
| cat > conftest_asm.s <<EOF |
| .string "test" |
| EOF |
| AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no") |
| LIBS=$saved_libs]) |
| if test "$ac_cv_c_asm_string" = "yes" |
| then |
| AC_DEFINE(HAVE_ASM_STRING) |
| fi |
| |
| dnl **** Check for working dll **** |
| |
| DLLFLAGS="" |
| if test "$LIB_TARGET" = "libwine.so.1.0" |
| then |
| AC_CACHE_CHECK("whether we can build a dll", |
| ac_cv_c_dll, |
| [saved_cflags=$CFLAGS |
| CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0" |
| AC_TRY_LINK(,[return 1],ac_cv_c_dll="yes",ac_cv_c_dll="no") |
| CFLAGS=$saved_cflags |
| ]) |
| if test "$ac_cv_c_dll" = "yes" |
| then |
| DLLFLAGS="-fPIC" |
| else |
| LIB_TARGET="libwine.a" |
| fi |
| fi |
| AC_SUBST(DLLFLAGS) |
| |
| dnl **** Check for reentrant X libraries **** |
| dnl |
| dnl This may fail to determine whether X libraries are reentrant if |
| dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration |
| dnl is possible with the --without-reentrant-x option. |
| |
| AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant, |
| [ if test "x$with_reentrant_x" = "xno" |
| then |
| wine_cv_x_reentrant=no |
| else |
| libX11_ckeck=none |
| for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do |
| if test -e $dir/libX11.so; then |
| libX11_check="-D $dir/libX11.so" |
| break 1 |
| fi |
| if test -e $dir/libX11.a; then |
| libX11_check="$dir/libX11.a" |
| break 1 |
| fi |
| done |
| if test "$libX11_check" != "none"; then |
| if nm $libX11_check | grep -q __errno_location; then |
| wine_cv_x_reentrant=yes |
| else |
| wine_cv_x_reentrant=no |
| fi |
| else |
| wine_cv_x_reentrant=unknown |
| fi |
| fi ] ) |
| if test "$wine_cv_x_reentrant" = "no" |
| then |
| AC_DEFINE(NO_REENTRANT_X11) |
| fi |
| |
| dnl **** Check for functions and header files **** |
| |
| AC_CHECK_FUNCS(clone memmove strerror tcgetattr timegm usleep wait4 waitpid) |
| AC_CHECK_HEADERS(wctype.h) |
| AC_HEADER_STAT() |
| AC_C_CONST() |
| AC_TYPE_SIZE_T() |
| |
| dnl **** Generate output files **** |
| |
| MAKE_RULES=Make.rules |
| AC_SUBST_FILE(MAKE_RULES) |
| |
| AC_OUTPUT([ |
| Make.rules |
| Makefile |
| controls/Makefile |
| debugger/Makefile |
| documentation/Makefile |
| files/Makefile |
| graphics/Makefile |
| graphics/metafiledrv/Makefile |
| graphics/win16drv/Makefile |
| graphics/x11drv/Makefile |
| if1632/Makefile |
| ipc/Makefile |
| library/Makefile |
| libtest/Makefile |
| loader/Makefile |
| memory/Makefile |
| misc/Makefile |
| miscemu/Makefile |
| msdos/Makefile |
| multimedia/Makefile |
| objects/Makefile |
| ole/Makefile |
| programs/Makefile |
| programs/clock/Makefile |
| programs/notepad/Makefile |
| programs/progman/Makefile |
| programs/view/Makefile |
| programs/winhelp/Makefile |
| programs/winver/Makefile |
| rc/Makefile |
| relay32/Makefile |
| resources/Makefile |
| scheduler/Makefile |
| tools/Makefile |
| tsx11/Makefile |
| win32/Makefile |
| windows/Makefile ]) |
| |
| echo |
| echo "Configure finished. Do 'make depend; make' to compile Wine." |
| echo |
| |
| dnl Local Variables: |
| dnl comment-start: "dnl " |
| dnl comment-end: "" |
| dnl comment-start-skip: "\\bdnl\\b\\s *" |
| dnl compile-command: "autoconf" |
| dnl End: |
